Object Detection and Bounding Boxes

In earlier sections (e.g., :numref:sec_alexnet–:numref:sec_googlenet), we introduced various models for image classification. In image classification tasks, we assume that there is only one major object in the image and we only focus on how to recognize its category. However, there are often multiple objects in the image of interest. We not only want to know their categories, but also their specific positions in the image. In computer vision, we refer to such tasks as object detection (or object recognition).

Object detection has been widely applied in many fields. For example, self-driving needs to plan traveling routes by detecting the positions of vehicles, pedestrians, roads, and obstacles in the captured video images. Besides, robots may use this technique to detect and localize objects of interest throughout its navigation of an environment. Moreover, security systems may need to detect abnormal objects, such as intruders or bombs.

In the next few sections, we will introduce several deep learning methods for object detection. We will begin with an introduction to positions (or locations) of objects.

using Pkg;
Pkg.activate("../../d2lai")
using d2lai, Images, Plots

  Activating project at `~/d2l-julia/d2lai`

We will load the sample image to be used in this section. We can see that there is a dog on the left side of the image and a cat on the right. They are the two major objects in this image.

img = load("../img/catdog.jpg")

Bounding Boxes

In object detection, we usually use a bounding box to describe the spatial location of an object. The bounding box is rectangular, which is determined by the $x$ and $y$ coordinates of the upper-left corner of the rectangle and the such coordinates of the lower-right corner. Another commonly used bounding box representation is the $(x,y)$-axis coordinates of the bounding box center, and the width and height of the box.

Here we define functions to convert between these (two representations): box_corner_to_center converts from the two-corner representation to the center-width-height presentation, and box_center_to_corner vice versa. The input argument boxes should be a two-dimensional tensor of shape ($n$, 4), where $n$ is the number of bounding boxes.

function box_corner_to_center(boxes)
    x1, y1, x2, y2 = boxes[:, 1], boxes[:, 2], boxes[:, 3], boxes[:, 4]
    cx = (x1 .+ x2) ./ 2
    cy = (y1 .+ y2) ./ 2
    w = x2 .- x1
    h = y2 .- y1
    boxes = stack((cx, cy, w, h), dims = 2)
    return boxes 
end

function boxes_center_to_corner(boxes)
    cx, cy, w, h =  boxes[:, 1], boxes[:, 2], boxes[:, 3], boxes[:, 4]
    x1 = cx - 0.5 * w
    y1 = cy - 0.5 * h
    x2 = cx + 0.5 * w
    y2 = cy + 0.5 * h
    boxes = stack((x1, y1, x2, y2), dims = 2)
    return boxes
end

boxes_center_to_corner (generic function with 1 method)

We will define the bounding boxes of the dog and the cat in the image based on the coordinate information. The origin of the coordinates in the image is the upper-left corner of the image, and to the right and down are the positive directions of the $x$ and $y$ axes, respectively.

dog_bbox, cat_bbox = [60.0, 45.0, 378.0, 516.0], [400.0, 112.0, 655.0, 493.0]

([60.0, 45.0, 378.0, 516.0], [400.0, 112.0, 655.0, 493.0])

We can verify the correctness of the two bounding box conversion functions by converting twice.

dog_bbox, cat_bbox = [60.0, 45.0, 378.0, 516.0], [400.0, 112.0, 655.0, 493.0]
boxes = stack((dog_bbox, cat_bbox), dims = 1)
boxes_center_to_corner(box_corner_to_center(boxes)) == boxes

true

Let's draw the bounding boxes in the image to check if they are accurate. Before drawing, we will define a helper function bbox_to_rect.

rectangle(w, h, x, y) = Shape(x .+ [0,w,w,0], y .+ [0,0,h,h])

function bbox_to_rect(plt, bbox, color, label = nothing)
    x1, y1, x2, y2 = bbox
    rect = rectangle(x2-x1, y2-y1, x1, y1)
    if !isnothing(label) 
        plot!(plt, rect, fillalpha=0, linecolor = color, label = label)
    else
        plot!(plt, rect, fillalpha=0, linecolor = color)
    end
    plt
end

bbox_to_rect (generic function with 2 methods)

After adding the bounding boxes on the image, we can see that the main outline of the two objects are basically inside the two boxes.

plt = plot(img)
bbox_to_rect(plt, dog_bbox, :red)
bbox_to_rect(plt, cat_bbox, :blue)

Summary

• Object detection not only recognizes all the objects of interest in the image, but also their positions. The position is generally represented by a rectangular bounding box.

• We can convert between two commonly used bounding box representations.

Exercises

1. Find another image and try to label a bounding box that contains the object. Compare labeling bounding boxes and categories: which usually takes longer?

2. Why is the innermost dimension of the input argument boxes of box_corner_to_center and box_center_to_corner always 4?